1 files changed, 53 insertions, 0 deletions
diff --git a/dev-ruby/webmock/webmock-1.22.3.ebuild b/dev-ruby/webmock/webmock-1.22.3.ebuild
new file mode 100644
index 0000000000..9dbacf4f68
--- /dev/null
+++ b/dev-ruby/webmock/webmock-1.22.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# ruby22 → spec failures
+USE_RUBY="ruby20 ruby21"
+
+RUBY_FAKEGEM_TASK_TEST="test spec NO_CONNECTION=true"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Allows stubbing HTTP requests and setting expectations on HTTP requests"
+HOMEPAGE="https://github.com/bblimke/webmock"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/addressable-2.3.6 >=dev-ruby/crack-0.3.2 dev-ruby/hashdiff"
+
+ruby_add_bdepend "test? (
+	dev-ruby/minitest:5
+	dev-ruby/rspec:3
+	dev-ruby/rack
+	>=dev-ruby/httpclient-2.2.4
+	>=dev-ruby/patron-0.4.18
+	>=dev-ruby/http-0.6.0:0.6 )"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	rm Gemfile || die
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# There is now optional support for curb and typhoeus which we don't
+	# have in Gentoo yet. em_http_request is available in Gentoo but its
+	# version is too old.
+	sed -i -e '/\(curb\|typhoeus\|em-http\)/d' spec/spec_helper.rb || die
+	rm spec/acceptance/{typhoeus,curb,excon,em_http_request}/* || die
+}
+
+each_ruby_test() {
+	${RUBY} -S rake test NO_CONNECTION=true || die
+	${RUBY} -S rspec-3 spec || die
+
+	einfo "Delay to allow the test server to stop"
+	sleep 10
+}